PDA

Visualizza versione completa : [WORD-EXCEL 2003] Fax in stampa unione


fisico73
29-11-2006, 17.52.19
Ciao a tutti, la funzione di "stampa unione" dovrebbe permettermi di mandare dei FAX. Invece l'icona relativa al fax rimane inattiva e non riesco a capire perchŔ. Ovviamente il mio fax funzina correttamente tanche che se faccio la "stampa" su fax riesco ad eseguirla correttamente ed il fax viene mandato (e ricevuto) senza problemi. Cosa sto sbagliando?

ciao e grazie dei consigli

evilboy
23-10-2008, 21.41.40
Ciao a tutti,
avevo la necessitÓ di creare una newsletter a mezzo FAX con tanto di intestazione dell'azienda... dunque ho pensato subito di utilizzare Word e la funzione Stampa unione per prelevare i vari dati da una tabella Excel.

Peccato che il tasto <Stampa Unione a FAX> fosse perennemente disabilitato.

Ho provato di tutto:
- reinstallare Windows FAX
- reinstallare Word
- reinstallare Outlook (non l'express)
- installare Winfax 10...
ma niente.

Per abilitare la funzione poi ho scoperto che bastava creare un file dentro la cartella di Windows con nome msmail.ini e metterci dentro:
[EFAX Transport]
LocalFax=1

Tutto bene? No... mi da l'errore "Impossibile inviare direttamente alla posta, al fax od alla stampante un catalogo creato unendo documenti".

Allora ho cercato di arrangiarmi in qualche altro modo e ho trovato questo interessante link: http://groups.google.it/group/microsoft.public.it.office.word/browse_thread/thread/2f5867eb27d896d1

In pratica con le macro si pu˛ fare in modo che venga stampata singolarmente ogni documento con l'intestazione, farlo passare su una stampante fax fornendogli numero e descrizione.

Andiamo per passi:
- si va nel men¨ Strumenti, si seleziona Macro e poi ancora Macro...
- si assegna un nome alla macro (tipo "FAX") e si seleziona il documento
- si preme il pulsante nuovo
- copiate dentro tutto questo testo: <vedi dopo>

- si entra nel men¨ Strumento dell'editor di marco e si seleziona Riferimenti...
- si abilitano le librerie faxcom e faxcontrol
- infine si salva.

Tutto finito??? non ancora...

Alcune piccole note:
- all'inizio del codice si pu˛ specificare dove creare i file tif di appoggio; la cartella deve essere creata (lui normalmente usa c:\tif)
- sempre all'inizio si pu˛ specificare il nome della stampante fax (lui normalmente usa "Fax")
- all'interno del codice lui ha bisogno di prelevare 2 dati: numero e descrizione
.FaxNumber = oDataFields("faxnumber")
.DisplayName = oDataFields("ufname")

quello che c'Ŕ tra le doppievirgolette deve coincidere con l'intestazione di colonna del file di dati sorgente. Se la colonna sia chiama "numeri di fax" dovete appunto metterci "numeri di fax".

A questo punto Ŕ sufficiente avviare la Macro e lui vi carica la stampante fax dei singoli documenti intestati che desiderate mandare.

Spero che possa rilevarsi utile per qualcuno.
Ciao.

evilboy
23-10-2008, 21.42.37
Prima parte
'-----------------------------------------------------
Sub MergeOneFaxPerSourceRec()

' Disclaimer: Use this macro at your own risk.
' Purpose: Perform one Word mailmerge for each record in
' a Word data source, sending the results of each
' merge to a different fax number specified in a
' column of the data source
' Author: Peter J Jamieson
' Date: November 2003
' Assumes: Word 2000 or later (Word 97 might work)
' Windows 2000 or later, with the standard
' fax service software installed and
' configured to use a working fax device
' You have used Tools|References in the VBA
' editor to add the appropriate type library
' ("Faxcom 1.0 Type Library")
' You correctly adapt the macro to your
' environment
' Overview: The routine performs one merge per record
' in the data source. For each merge, the macro:
' - creates a new Word document
' - "prints" the document to the Fax printer,
' but outputting the result to a .tif file
' rather than allowing the fax printer to
' send the fax directly. This allows us to
' specify the fax number etc. in the macro
' rather than having to respond to the fax
' printer's dialog box.
' - submits the tif file to the fax service
' - discards the Word document
'
' Notes: This does not use the Extended Fax client API
' because it is not available in Windows 2000.
'
' This macro relies on the fax service to deliver
' the faxes once trhey have been submitted. You
' should use the fax service to verify which faxes
' have been sent and which, if any, failed. The fax
' service should retain a copy of each fax submitted
' so that retransmission should be feasible from
' within the service, i.e. without re-running the
' merge.

' NB, needs bettor error management and doubtless other
' things a VBA expert would point out.

' Specify the path for the .tif files saved by the Fax Printer
' This path must exist and the name should end with "\"
Const sTifFolder = "c:\tif\"
' Specify the name of the .tif file to output
Const sTifFile = "mergetif.tif"
' Specify the fax printer name that makes it all work
Const sFaxPrinter = "Fax"

Dim bFaxPortAvailable As Boolean
Dim bFaxServerAvailable As Boolean

Dim bTerminateMerge As Boolean

Dim lJobID As Long
Dim lSourceRecord As Long

Dim oApp As Word.Application
Dim oDataFields As Word.MailMergeDataFields
Dim oDoc As Word.Document
Dim oFaxDoc As FAXCOMLib.FaxDoc
Dim oFaxPort As FAXCOMLib.FaxPort
Dim oFaxPorts As FAXCOMLib.FaxPorts
Dim oFaxServer As FAXCOMLib.FaxServer
Dim oMerge As Word.MailMerge

Dim sActivePrinter As String
Dim sTifPath As String

' Phase 1.
' Connect to the Fax server
' and optionally see if a Port is available

Set oFaxServer = CreateObject("FaxServer.FaxServer")

If oFaxServer Is Nothing Then
MsgBox "Could not create a fax server object"
bFaxServerAvailable = False
Else
' This should connect us to the fax server on the current machine
oFaxServer.Connect Servername:=Environ("computername")
bFaxServerAvailable = True
bFaxPortAvailable = True

' begin optional section
' - ensure that at least one output port is available
' - not essential but we will just see an error later
' if no output port is available
Set oFaxPorts = oFaxServer.GetPorts
If oFaxPorts.Count = 0 Then
MsgBox "The fax server has no fax devices"
bFaxPortAvailable = False
Else
' look for a port that can send
For i = 1 To oFaxPorts.Count
Set oFaxPort = oFaxPorts.Item(i)
If oFaxPort.Send = 0 Then
Set oFaxPort = Nothing
Else
Exit For
End If
Next
If oFaxPort Is Nothing Then
MsgBox "The fax server has no ports configured to send faxes"
bFaxPortAvailable = False
Else
' at the moment we do not use the FaxPort object to get status
' info. so just get rid of it
Set oFaxPort = Nothing
End If
End If
' we do not need this either
Set oFaxPorts = Nothing
' end optional section

End If

' Phase 2.
' We can fax, so set up the printer
' and start the merges.

If bFaxServerAvailable And bFaxPortAvailable Then

' You may need to change this
Set oApp = Application

' The mail merge main document is assumed
' to be the active document in the current
' instance of Word
Set oDoc = oApp.ActiveDocument
Set oMerge = oDoc.MailMerge
Set oDataFields = oMerge.DataSource.DataFields

' save and set up the active printer
sActivePrinter = oApp.ActivePrinter
' don't change the printer if it is already
' correctly set up
' (I had problems when I tried to switch
' to the fax printer in code)
' you may need to adjust this for your
' fax printer name
If Left(sActivePrinter, 3) <> sFaxPrinter Then
oApp.ActivePrinter = sFaxPrinter
End If

evilboy
23-10-2008, 21.43.05
Seconda parte
With oMerge

' If no data source has been defined,
' do it here using OpenDataSource.
' But if it is already defined in the document,
' you should not need to define it here.

' .OpenDataSource _
' Name:="whatever"

lSourceRecord = 1
bTerminateMerge = False

Do Until bTerminateMerge
.DataSource.ActiveRecord = lSourceRecord

' if we have gone past the end
' (and possibly, if there are no records)
' then the Activerecord will not be what
' we have just tried to set it to

If .DataSource.ActiveRecord <> lSourceRecord Then
bTerminateMerge = True
Else
.DataSource.FirstRecord = lSourceRecord
.DataSource.LastRecord = lSourceRecord
.Destination = wdSendToNewDocument
.Execute

' Word always sets the output document produced
' by the merge to be the ActiveDocument

' Now print to the fax printer, specifying an
' OutputFileName.
' Specifying Background:=False is
' particularly important or the fax stage
' will fail later

' create the full path name for the file.
' (done separately so you can change the way
' you create the name and re-use the name later)

sTifPath = sTifFolder + sTifFile
oApp.PrintOut _
Background:=False, _
Append:=False, _
Range:=wdPrintAllDocument, _
OutputFileName:=sTifPath, _
Item:=wdPrintDocumentContent, _
Copies:=1, _
PageType:=wdPrintAllPages, _
PrintToFile:=True

' Don't need the document any more
oApp.ActiveDocument.Close Savechanges:=False

' Now make a FaxDocument
Set oFaxDoc = oFaxServer.CreateDocument(sTifPath)
If oFaxDoc Is Nothing Then
MsgBox "Could not create the fax document"
' you could consider finishing here by setting
' TerminateMerge = True
Else
' fill in whatever details you need
' from the data source or elsewhere
With oFaxDoc
' The number to send to. The only really essential
' piece of information. Here we get it from
' a field in the data source called "faxnumber"
.FaxNumber = oDataFields("faxnumber")

' DisplayName is a "user-friendly" name used
' by the Fax Server when you e.g. inspect the
' current fax status

' here we get it from a field in the data source
' called ufname
.DisplayName = oDataFields("ufname")
' here we just set it to ""
'.DisplayName = ""

' If you want a cover page, set SendCoverPage
' to a nonzero value. You could define whether
' or not you want a cover page, and which
' page to use, in your data source. However,
' if you specify a cover page, you /must/
' provide a valid name for the page. This code
' does not verify whether you do or not.
.SendCoverpage = 0

' If the cover page (.cov file) is a common
' cover page located on the server (i.e. in the
' default folder), set ServerCoverPage=-1
' and provide the name of the cover page
' If the cover page is somewhere else,
' set ServerCoverPage=0 and specify the
' full path name of the cover page
.ServerCoverpage = 1
.CoverpageName = ""

' The following items may be used in the coverpage
' or they may be displayed in fax service status
' dialog boxes. The items visible in the Win2000
' fax status are indicated by
'** displayed in dialog

.CoverpageNote = ""
.CoverpageSubject = ""
.EmailAddress = ""
.RecipientAddress = ""
.RecipientCity = ""
.RecipientCompany = ""
.RecipientCountry = ""
.RecipientDepartment = ""
.RecipientHomePhone = ""
'** displayed in dialog
.RecipientName = ""
.RecipientOffice = ""
.RecipientOfficePhone = ""
.RecipientState = ""
.RecipientTitle = ""
.RecipientZip = ""
.SenderAddress = ""
'** displayed in dialog
.SenderCompany = ""
'** displayed in dialog
.SenderDepartment = ""
.SenderFax = ""
.SenderHomePhone = ""
'** displayed in dialog
.SenderName = ""
.SenderOffice = ""
.SenderOfficePhone = ""
.SenderTitle = ""

'** displayed in dialog
.BillingCode = ""

' DiscountSend = 0 means "send immediately
' If you have set up discount periods, setting
' DiscountSend to a nonzero value will make the
' fax service send in a discount period
.DiscountSend = 0

' In theory, the TSID is the Fax sender ID printed
' on the fax, i.e. typically your contact fax number,
' but the value set up in the fax service appears to
' override any value set here.
'.Tsid = ""
End With

' Now send the thing. We don't actually do anything
' with the ID except check it is nonzero

lJobID = oFaxDoc.Send()
Set oFaxDoc = Nothing
End If
End If
' move to the next record
lSourceRecord = lSourceRecord + 1
Loop
End With

' All done. Restore the previous printer
' if necessary. You may need to tweak this
If Left(sActivePrinter, 3) <> sFaxPrinter Then
oApp.ActivePrinter = sActivePrinter
End If

Set oDataFields = Nothing
Set oMerge = Nothing
Set oDoc = Nothing

'Set oApp = Nothing

End If

If bFaxServerAvailable Then
oFaxServer.Disconnect
Set oFaxServer = Nothing
End If

End Sub